*&---------------------------------------------------------------------*
*& Report demo_cfw *
*&---------------------------------------------------------------------*

REPORT demo_cfw.

*&---------------------------------------------------------------------*
*& Global Declarations *
*&---------------------------------------------------------------------*

* Class Definitions

CLASS screen_handler DEFINITION CREATE PRIVATE.
PUBLIC SECTION.
CLASS-DATA screen TYPE REF TO screen_handler.
CLASS-METHODS create_screen.
METHODS constructor.
PRIVATE SECTION.
DATA: container_html TYPE REF TO cl_gui_custom_container,
container_box TYPE REF TO cl_gui_dialogbox_container,
picture TYPE REF TO cl_gui_picture,
tree TYPE REF TO cl_gui_simple_tree,
html_viewer TYPE REF TO cl_gui_html_viewer,
list_viewer TYPE REF TO cl_gui_alv_grid.
METHODS: fill_tree,
fill_picture,
handle_node_double_click
FOR EVENT node_double_click OF cl_gui_simple_tree
IMPORTING node_key,
close_box
FOR EVENT close OF cl_gui_dialogbox_container,
fill_html IMPORTING i_carrid TYPE spfli-carrid,
fill_list IMPORTING i_carrid TYPE spfli-carrid
i_connid TYPE spfli-connid.
ENDCLASS. "screen_handler DEFINITION

* Class Implementations

CLASS screen_handler IMPLEMENTATION.

METHOD create_screen.
IF screen IS INITIAL.
CREATE OBJECT screen.
ENDIF.
ENDMETHOD. "create_screen

METHOD constructor.
DATA: l_event_tab TYPE cntl_simple_events,
l_event LIKE LINE OF l_event_tab,
l_docking TYPE REF TO cl_gui_docking_container,
l_splitter TYPE REF TO cl_gui_splitter_container,
l_container_screen TYPE REF TO cl_gui_custom_container,
l_container_top TYPE REF TO cl_gui_container,
l_container_bottom TYPE REF TO cl_gui_container.

CREATE OBJECT container\_html  
       EXPORTING container\_name = 'CUSTOM\_CONTROL'.

CREATE OBJECT l\_docking  
       EXPORTING side = cl\_gui\_docking\_container=>dock\_at\_left  
                 extension = 135.

CREATE OBJECT l\_splitter  
       EXPORTING parent = l\_docking  
                 rows = 2  
                 columns = 1.

l\_splitter->set\_border(  
     EXPORTING border = cl\_gui\_cfw=>false ).

l\_splitter->set\_row\_mode(  
     EXPORTING mode = l\_splitter->mode\_absolute ).

l\_splitter->set\_row\_height(  
     EXPORTING id = 1  
               height = 180 ).

l\_container\_top    =  
  l\_splitter->get\_container( row = 1 column = 1 ).  
l\_container\_bottom =  
  l\_splitter->get\_container( row = 2 column = 1 ).

CREATE OBJECT picture  
       EXPORTING parent = l\_container\_top.

CREATE OBJECT tree  
       EXPORTING parent = l\_container\_bottom  
                 node\_selection\_mode =  
                   cl\_gui\_simple\_tree=>node\_sel\_mode\_single.

l\_event-eventid = cl\_gui\_simple\_tree=>eventid\_node\_double\_click.  
l\_event-appl\_event = ' '.   "system event, does not trigger PAI  
APPEND l\_event TO l\_event\_tab.  
tree->set\_registered\_events(  
     EXPORTING events = l\_event\_tab ).  
SET HANDLER me->handle\_node\_double\_click FOR tree.

me->fill\_picture( ).  
me->fill\_tree( ).  

ENDMETHOD. "constructor

METHOD fill_picture.
TYPES pict_line TYPE x LENGTH 1022.
DATA l_mime_api TYPE REF TO if_mr_api.
DATA l_pict_wa TYPE xstring.
DATA l_pict_tab TYPE TABLE OF pict_line.
DATA l_url TYPE c LENGTH 255.

l\_mime\_api = cl\_mime\_repository\_api=>get\_api( ).

l\_mime\_api->get(  
  EXPORTING i\_url = '/SAP/PUBLIC/BC/ABAP/Sources/PLANE.GIF'  
  IMPORTING e\_content = l\_pict\_wa  
  EXCEPTIONS OTHERS = 4 ).

IF sy-subrc <> 0.  
  RETURN.  
ENDIF.

l\_pict\_tab =  
  VALUE #( LET l1 = xstrlen( l\_pict\_wa ) l2 = l1 - 1022 IN  
           FOR j = 0 THEN j + 1022  UNTIL j >= l1  
             ( COND #( WHEN j <= l2 THEN  
                            l\_pict\_wa+j(1022)  
                       ELSE l\_pict\_wa+j ) ) ).

CALL FUNCTION 'DP\_CREATE\_URL'  
  EXPORTING  
    type    = 'IMAGE'  
    subtype = 'GIF'  
  TABLES  
    data    = l\_pict\_tab  
  CHANGING  
    url     = l\_url.

picture->load\_picture\_from\_url(  
     EXPORTING url = l\_url ).  
picture->set\_display\_mode(  
     EXPORTING display\_mode = picture->display\_mode\_stretch ).  

ENDMETHOD. "fill_picture

METHOD fill_tree.
DATA: l_node_table TYPE TABLE OF abdemonode,
l_node TYPE abdemonode,
BEGIN OF l_spfli,
carrid TYPE spfli-carrid,
connid TYPE spfli-connid,
END OF l_spfli,
l_spfli_tab LIKE SORTED TABLE OF l_spfli
WITH UNIQUE KEY carrid connid.

SELECT carrid, connid  
  FROM spfli  
  INTO CORRESPONDING FIELDS OF TABLE @l\_spfli\_tab.

l\_node-hidden = ' '.               " All nodes are visible,  
l\_node-disabled = ' '.             " selectable,  
l\_node-isfolder = 'X'.             " a folder,  
l\_node-expander = ' '.             " have no '+' sign for expansion.

LOOP AT l\_spfli\_tab INTO l\_spfli.  
  AT NEW carrid.  
    l\_node-node\_key = l\_spfli-carrid.  
    CLEAR l\_node-relatkey.  
    CLEAR l\_node-relatship.  
    l\_node-text = l\_spfli-carrid.  
    l\_node-n\_image =   ' '.  
    l\_node-exp\_image = ' '.  
    APPEND l\_node TO l\_node\_table.  
  ENDAT.  
  AT NEW connid.  
    l\_node-node\_key = l\_spfli-carrid && l\_spfli-connid.  
    l\_node-relatkey = l\_spfli-carrid.  
    l\_node-relatship = cl\_gui\_simple\_tree=>relat\_last\_child.  
    l\_node-text = l\_spfli-connid.  
    l\_node-n\_image =   '@AV@'.     "AV is the internal code  
    l\_node-exp\_image = '@AV@'.     "for an airplane icon  
  ENDAT.  
  APPEND l\_node TO l\_node\_table.  
ENDLOOP.

tree->add\_nodes(  
     EXPORTING table\_structure\_name = 'ABDEMONODE'  
               node\_table = l\_node\_table ).  

ENDMETHOD. "fill_tree

METHOD handle_node_double_click.
DATA: l_carrid TYPE spfli-carrid,
l_connid TYPE spfli-connid.

l\_carrid = node\_key(2).  
l\_connid = node\_key+2(4).  
IF l\_connid IS INITIAL.  
  fill\_html( EXPORTING i\_carrid = l\_carrid ).  
ELSE.  
  fill\_list( EXPORTING i\_carrid = l\_carrid  
                       i\_connid = l\_connid ).  
ENDIF.  

ENDMETHOD. "handle_node_double_click

METHOD fill_html.
DATA l_url TYPE scarr-url.

IF html\_viewer IS INITIAL.  
  CREATE OBJECT html\_viewer  
         EXPORTING parent = container\_html.  
ENDIF.

SELECT SINGLE url  
       FROM   scarr  
       WHERE  carrid = @i\_carrid  
       INTO   @l\_url.

html\_viewer->show\_url(  
     EXPORTING url = l\_url ).  

ENDMETHOD. "fill_html

METHOD fill_list.
DATA: l_flight_tab TYPE TABLE OF demofli,
BEGIN OF l_flight_title,
carrname TYPE scarr-carrname,
cityfrom TYPE spfli-cityfrom,
cityto TYPE spfli-cityto,
END OF l_flight_title,
l_list_layout TYPE lvc_s_layo.

IF container\_box IS INITIAL.  
  CREATE OBJECT container\_box  
         EXPORTING width  = 250  
                   height = 200  
                   top    = 100  
                   left   = 400  
                   caption = 'Flight List'.  
  SET HANDLER close\_box FOR container\_box.  
  CREATE OBJECT list\_viewer  
         EXPORTING i\_parent = container\_box.  
ENDIF.

SELECT SINGLE c~carrname, p~cityfrom, p~cityto  
       FROM   ( scarr AS c  
                  INNER JOIN spfli AS p ON c~carrid = p~carrid )  
       WHERE  p~carrid = @i\_carrid AND  
              p~connid = @i\_connid  
       INTO   CORRESPONDING FIELDS OF @l\_flight\_title.

SELECT   fldate, seatsmax, seatsocc  
         FROM     sflight  
         WHERE    carrid = @i\_carrid AND connid = @i\_connid  
         ORDER BY fldate  
         INTO     CORRESPONDING FIELDS OF TABLE @l\_flight\_tab.

l\_list\_layout-grid\_title = l\_flight\_title-carrname && \` \` &&  
                           i\_connid                && \` \` &&  
                           l\_flight\_title-cityfrom && \` \` &&  
                           l\_flight\_title-cityto.

l\_list\_layout-smalltitle = 'X'.    "The list title has small fonts,  
l\_list\_layout-cwidth\_opt = 'X'.    "the column width is adjusted,  
l\_list\_layout-no\_toolbar = 'X'.    "the toolbar is suppressed.

list\_viewer->set\_table\_for\_first\_display(  
     EXPORTING i\_structure\_name = 'DEMOFLI'  
               is\_layout        = l\_list\_layout  
     CHANGING  it\_outtab        = l\_flight\_tab ).  

ENDMETHOD. "fill_list

METHOD close_box.
list_viewer->free( ).
container_box->free( ).
CLEAR: list_viewer,
container_box.
ENDMETHOD. "close_box

ENDCLASS. "screen_handler IMPLEMENTATION

*&---------------------------------------------------------------------*
*& Processing Blocks called by the Runtime Environment *
*&---------------------------------------------------------------------*

* Event Block START-OF-SELECTION

START-OF-SELECTION.
CALL SCREEN 100.

* Dialog Module PBO

MODULE status_0100 OUTPUT.
SET PF-STATUS 'SCREEN_100'.
SET TITLEBAR 'TIT_100'.
screen_handler=>create_screen( ).
ENDMODULE. "status_0100 OUTPUT

* Dialog Module PAI

MODULE cancel INPUT.
LEAVE PROGRAM.
ENDMODULE. "cancel INPUT

Description

On the screen layout of screen 100 is a Custom Control named CUSTOM_CONTROL that covers the entire screen area. In the flow logic, both dialog modules STATUS_0100 and CANCEL are called at which the addition AT EXIT-COMMAND is used for PAI.

In GUI status SCREEN_100, the common symbols of the status bar are occupied with function codes of the type E. The PAI module only serves to exit the program. The most important action to PBO is calling the static method create_screen of the local class screen_handler, in which an object of this class is created.

The instance constructor of the class screen_handler generates container controls for a Picture Control and a Tree Control and afterwards both application controls.

• First, a Docking Control is created with the local reference variable l_docking. By transferring the constant dock_at_left of the class CL_GUI_DOCKING_CONTAINER to the parameter side, a new area is created on the left side of the screen with a width of 135 pixels.

• This screen area is split into two horizontal areas. This is achieved via the local reference variable l_splitter, which creates an object of the class CL_GUI_SPLITTER_CONTAINER and transfers the reference to the Docking Control to the parameter parent.

• Using the functional method get_container, the references to both areas of the splitter-control are determined in the local reference variables l_container_top and l_container_bottom . Afterwards, the application-controls Picture and Tree are generated, at which the parameter parent of each constructor receives one of the references to the areas of the splitter control.

By calling the method set_registered_events, the doubleclick event for the nodes of the tree are activated as system event. The method handle_node_double_click is registered as event handler.

When leaving the instance constructor, all reference variables are deleted. However, the control objects generated in the constructor with local reference variables are not collected by the garbage collection, as they are maintained by references from the CFW.

The method fill_picture imports an image file in GIF format from the MIME Repository into a byte string l_pict_wa, which is then filled into an internal table l_pict_tab. The function module DP_CREATE_URL generates an URL address for this table in the local variable l_url, which is passed to the method load_picture_from_url of the Picture Control.

The method fill_tree generates the tree structure of the tree control in the internal table l_node_table of the row structure ABDEMONODE. Every row of the table describes a node of the tree structure and must have a unique node key node_key for it. The components relatkey and relatship describe the relationships among the nodes.

The node table is generated from the content of the database table SPFLI. At the subnodes, the standard icons for non-expanded and expanded nodes are replaced with aircraft icons.

The event handler method handle_node_double_click imports the parameter node_key of the event node_double_click of the class CL_GUI_SIMPLE_TREE, which contains the key of the selected node. Depending on the content, the methods fill_html or fill_list are called.

When the method fill_html is called for the first time, it generates an object of the class CL_GUI_HTML_VIEWER and links the associated HTML control with the area of the container control to which the reference in container_html points (with the Custom Control on the screen). According to the selected node, the web address of an airline is read and handed over to the method show_url of the HTML control, by which the Homepage of the airline is displayed.

The method fill_list generates a dialog box container and an ALV Grid Control that is displayed in the dialog box. The event handler close_box is registered for the dialog box container. Activation using the method set_registered_events is not necessary here, as the event is activated by the class itself as system event when the object is generated. A list is generated for the selected nodes. By assigning values to some components of the structure l_list_layout of the type lvc_s_layo, it is determined that the list title in displayed in small format, and that the column width of the list is optimized, and that the list should not have an application toolbar. By calling the method set_table_for_first_display of the ALV Grid Control, the list is displayed in the dialog box.

You use the event handler method close_box to close the dialog box. To do this, you call the methods free of the concerned controls one after another and then initialize the respective reference variables. After that, if a node is selected to generate a list, both controls are created again in the method fill_list. All other controls of the program cannot be deleted by the user and will be available until the program ends.

Note

The class CL_SALV_TABLE and other classes with the prefix CL_SALV_ meanwhile offer more comfortable ways of displaying ALV Controls.