在上一节的代码上进行修改，如下：

Shader "Custom/BasicDiffuse"
{
    Properties
    {
        _EmissiveColor("Emissive Color",color) = (1,1,1,1)
        _AmbientColor("Ambient Color",color) = (1,1,1,1)
        _MySliderValue("This is a Slider",Range(0,10)) = 2.5
    }

        SubShader
    {
        Tags{"RenderType" = "Opaque"}
        LOD 200

        CGPROGRAM
        #pragma surface surf BasicDiffuse

        float4 _EmissiveColor;
        float4 _AmbientColor;
        float _MySliderValue;

        struct Input 
        {
            float2 uv_MainTex;
        };

        void surf(Input IN,inout SurfaceOutput o) 
        {
            float4 c;
            c = pow((_EmissiveColor + _AmbientColor), _MySliderValue);

            o.Albedo = c.rgb;
            o.Alpha = c.a;
        }

        inline float4 LightingBasicDiffuse(SurfaceOutput s, fixed3 lightDir, fixed atten)
        {
            float difLight = max(0, dot(s.Normal, lightDir));
            float4 col;
            col.rgb = s.Albedo * _LightColor0.rgb * (difLight * atten * 2);
            col.a = s.Alpha;
            return col;
        }
        ENDCG
    }
        FallBack "Diffuse"
}

 修改内容是为了删除Unity自带的漫反射光照，并且实现一个可以自定义的光照模型。

实现原理

（1）

#pragma surface指令告诉着色器将使用哪个光照模型来计算。

这里将

#pragma surface surf Lambert

修改为

#pragma surface surf BasicDiffuse

就是让着色器由默认使用的Lighting.oginc文件里包含的Lambert光照模型修改为自定义的名为BasicDiffuse的光照模型。

（2）

然后，编写光照模型函数，有三种格式：

half4 LightName(SurfaceOutput s, half3 lightDir, half atten){}

该函数用于不需要视角方向的前向着色。

half4 LightName(SurfaceOutput s, half3 lightDir,half3 viewDir,half atten){}

该函数用于需要视角方向的前向着色。

half4 LightName_PrePass(SurfaceOutput s, half4 light){}

该函数用于需要使用延迟着色的项目。

此外，函数名可以自拟。格式为Lighting+任意名字。

（3）

点积函数（dot product function）

Cg语言的一个内置数学函数，用来比较两个向量在空间里的方向。

任意两个向量都可以通过点积函数获得-1~1的夹角范围，-1表示平行向量但方向相背，1表示平行向量但方向相同，0表示垂直方向的向量。

（4）

max函数

max函数有两个参数，最终返回两个参数中的最大值。

这里，用于限制点积函数的计算结果，确保漫反射的计算结果永远介于0和点积最大值之间。

这样就不会得到小于0的值，否则可能会在使用的着色器区间生成极度黑色的区域，并且在之后的着色器运算过程中容易出现问题。

（5）

将Unity和SurfaceOutput结构体提供的数据做乘法运算，完成漫反射计算。